Files
SakuraHub/scripts/build_mobile_android.bat
T
2026-11-16 20:45:22 +08:00

53 lines
1.3 KiB
Batchfile

@echo off
setlocal
cd /d "%~dp0\.."
if defined JAVA_HOME goto java_ready
if exist "E:\path\Zulu\Zulu\zulu-21\bin\java.exe" (
set "JAVA_HOME=E:\path\Zulu\Zulu\zulu-21"
goto java_ready
)
if exist "E:\path\java-21\bin\java.exe" (
set "JAVA_HOME=E:\path\java-21"
goto java_ready
)
if exist "E:\path\Zulu\Zulu\bin\java.exe" (
set "JAVA_HOME=E:\path\Zulu\Zulu"
goto java_ready
)
echo JDK 17+ was not found. Set JAVA_HOME to a JDK 17 or newer installation first.
pause
exit /b 1
:java_ready
set "ANDROID_SDK_ROOT=%CD%\tools\android-sdk"
set "ANDROID_HOME=%ANDROID_SDK_ROOT%"
set "PUB_CACHE=%CD%\tools\pub-cache"
set "PATH=%CD%\tools\flutter\bin;%JAVA_HOME%\bin;%ANDROID_SDK_ROOT%\cmdline-tools\latest\bin;%ANDROID_SDK_ROOT%\platform-tools;%PATH%"
where flutter >nul 2>nul
if errorlevel 1 (
echo Flutter was not found. Expected tools\flutter\bin\flutter.bat.
pause
exit /b 1
)
cd /d "%~dp0\..\sakura_mobile"
if not exist "android\app" (
echo Android project files are missing. Restore the sakura_mobile\android directory first.
pause
exit /b 1
)
call "%CD%\..\tools\flutter\bin\flutter.bat" pub get
if errorlevel 1 exit /b 1
call "%CD%\..\tools\flutter\bin\flutter.bat" build apk --release
if errorlevel 1 exit /b 1
echo.
echo Android APK output: build\app\outputs\flutter-apk\app-release.apk
if "%BUILD_NO_PAUSE%"=="" pause